@title Rastros
@start Beginning
[[Beginning]]:
@clear
@set puntaje =0
@set not traje_puesto
@set not tengo_pala
@set not tengo_chuzo
R a s t r o s
versión 01.01.01
Mi reloj de sobremesa suena con ese zumbido en crescendo, insistente y molesto, que nunca falla en hacerme abrir los ojos.
Desconecto la alarma, [bostezo] y me estiro.
Más dormido que despierto, camino hacia el [cuarto de baño]; la [ducha fría] termina de despabilarme.
Ya vestido con el [mono de trabajo] y con un café en el cuerpo, estoy "listo" para otro día de trabajo más.
Un [[nuevo día]] en la Estación botánica Nº23.
[bostezo]:
Aún no termino de acostumbrarme a los horarios de trabajo; cosa de uso horario, supongo, porque aquí se trabaja de sol a sol.
[cuarto de baño]:
El cuarto de baño es espartano pero funcional: un lavabo, un retrete y una ducha... sin cortina, por cierto; no hay nadie más en la estación, así que ¿Para qué complicarse con esas consideraciones?
[ducha fría]:
Una ducha diaria es todo un lujo, pero ducha caliente sería un lujo inútil; afuera hace calor casi siempre y por lo demás el duchazo es intenso y breve. Podría tomar más de una ducha al día, pero con esa temperatura de agua en general no me apetece...
[mono de trabajo]:
El mono de trabajo es de una sola pieza de tela delgada pero resistente, con las botas incorporadas y unas buenas suelas de seguridad. Los guantes pueden dejarse colgando, pero rara vez lo hago; las manos respiran bien con los guantes puestos y por el tipo de trabajo, no es conveniente... ni sano.
[[nuevo día]]:
@clear
Me asomo afuera del [refugio] y veo que la entrada está limpia: no hay huellas ni restos animales... así que, para variar, ha sido una noche [tranquila].
Ahora podría [[coger una fruta]] para completar mi desayuno o [[irme directo al cobertizo de herramientas]](cobertizo de herramientas).
[refugio]:
El refugio subterráneo es un hexágono bajo y es la estructura más sólida de la estación. Las paredes, de 2 metros de grosor, son de concreto sólido y completamente inexpugnables. En un apuro, puede servir de búnker (estanco incluído) por una semana o así... y se agradece, la verdad.
[tranquila]:
La verdad, nunca me entero de qué pasa de noche; las paredes del refugio no dejan pasar sonido o vibración externa alguna. Duermo sin interrupciones y cuando salgo todo es una sorpresa.
No siempre buena, por cierto.
[[coger una fruta]]:
@clear
Me decido por la fruta; café aparte, empezar el trabajo de la mañana sin energía es mala idea.
El [camino] a los frutales está limpio también; parece que mi día comienza definitivamente muy bien... o al menos con cara de que será más descansado que [ayer]; eso mejora mi humor casi tanto como la perspectiva de comerme una fruta.
Salvo algún fruto caído de los árboles anoche, todo se ve en [orden] en este lote de la estación.
Una de las manzanas llama mi atención: es casi tan grande como mi cabeza. Supongo que podría [[llevarla al laboratorio]](laboratorio) y tomar alguna muestra... [[o podría pasar de ello]](no laboratorio).
[camino]:
Los caminos y senderos de la estación están hechos de roca fundida con cemento y desechos industriales. A los bichos no les ha dado por mordisquearlo... a la fecha, vaya.
[ayer]:
Ayer tuve que fumigar. Un coñazo pero si no se hace a tiempo, las cosas se desmadran rápidamente.
[orden]:
Mantener tanta limpieza aquí y allá es un latazo, pero, en general, los terrenos despejados y limpios no atraen a los bichos, lo que es buena cosa.
[[laboratorio]]:
@inc puntaje
...y como de esto se trata en buena medida el trabajo en la Estación botánica Nº23, cojo la manzana (que pesa lo suyo), me devuelvo al refugio y, rodeándolo, entro al [laboratorio] que está detrás.
Todo está en orden en mi mesa de trabajo, así que, sin mayor demora, troceo la manzana, separando el corazón del resto de la pulpa; pongo el corazón en un frasco para muestras y, sellando bien la tapa, lo meto en el tubo neumático de envío.
Me he comido casi toda la fruta (buenísima, por cierto) antes de que el tubo devuelva el frasco con una [nota verde] de respuesta dentro. Decido que la nota puede esperar; ya es hora de [[ir al cobertizo de herramientas]](cobertizo de herramientas).
[laboratorio]:
El laboratorio también es subterráneo y es tan estanco e inexpugnable como el refugio. No tiene provisiones, pero desde aquí al menos puedes pedir ayuda... y cruzar los dedos.
[nota verde]:
Las notas de respuesta verdes suelen tener indicaciones para cambiar las mezclas para fertilizante o fumigación: química agrícola de mantención; nada urgente, vamos, que si no, los chicos de la [Estación Central] me habrían mandado una nota amarilla, como mínimo. Así las cosas, mejor me dedico a la rutina programada para hoy.
[Estación Central]:
La Estación Central está más o menos al centro de las demás estaciones y desde ahí nos despachan los trabajos a cada estación.
[[no laboratorio]]:
La verdad, no quiero demorarme demasiado con el desayuno, así que cojo una manzana cualquiera y me la como [[camino del cobertizo de herramientas]](cobertizo de herramientas).
[[cobertizo de herramientas]]:
@clear
{if seen coger una fruta:Con la fruta en el cuerpo, llego al cobertizo de buena gana y a paso vivo.}
{else:En general, no es buena idea comenzar la faena diaria sin energías, pero ver la entrada del refugio limpia me ha puesto de muy buen humor y eso es casi tan bueno como una fruta por la mañana.}
Ayer por la tarde fumigué a conciencia, así que no es sorpresa encontrar el [cobertizo] sin signos de que algún bicho se haya aproximado al lugar.
Buena cosa. Se dice rápido, pero sin bichos cerca todo va mejor.
Lo cierto es que la rejilla de las paredes es incomestible, pero es un latazo estar limpiando [babas] de las herramientas y todo lo demás: algunas alimañas tiene lenguas o bocas o qué sé yo así de largas... y la noche, para bichos que no tienen nada mejor que hacer que joder con el cobertizo, es larga.
Abro el candado con la [huella] de mi pulgar e inspecciono el interior: todo se ve como lo dejé ayer; los [trajes] para control de plagas colgando del techo, las palas, picotas y chuzos en su sitio y los frascos y sacos de [químicos] dentro de su [baúl] transparente bien cerrado... y sin "visitas" a la vista, dentro o fuera del baúl.
Para el trabajo de hoy, puedo [[coger una pala]](pala) y cavar hoyos para sembrar plantas o bien [[hacerme de un chuzo]](chuzo) para picar tierra en el terreno que tengo en barbecho.
[cobertizo]:
El cobertizo de herramientas está en una estructura elevada sobre el suelo, para evitar problemas con la humedad si hay fallas de riego; contra los bichos, si no es subterráneo y blindado, da lo mismo si está en altura o no.
[babas]:
Algunas de las "secreciones" de estos bichos son corrosivas, si se las deja estar más de un día sin limpiar.
[huella]:
El lector funciona a través de mis guantes: buen diseño, joder; otra buena cosa salida de la [Estación Central].
[Estación Central]:
La Estación Central está más o menos al centro de las demás estaciones y desde ahí nos despachan los trabajos a cada estación. Con la carga de trabajo que tienen, cuesta creer que tengan tiempo para tanta maravilla técnica, pero es que ahí solo trabajan los mejores... y a sobre tiempo, que me consta.
[trajes]:
Los trajes de control de plagas son como mi mono de trabajo, pero mucho más gruesos e incómodos: están presurizados, con escafandra y sistema de aire autónomo. No es que me guste ponérmelos, pero ni de madres se me ocurriría hacer fumigación sin eso puesto. El mono de trabajo es seguro, pero no es estanco ni blindado...
[químicos]:
Los químicos tienen etiquetas codificadas con símbolos, pero tanto da: sin instrucciones precisas, ponerse a hacer mezclas "por deporte" es tentar tu suerte; allá afuera, hay cráteres que lo demuestran.
[baúl]:
No sé de qué estará hecho el baúl, pero entiendo que podría pasar una erupción volcánica encima y ni se calentaría. También puede aguantar descompresiones violentas. Material de primera, ya te digo.
[[pala]]:
@clear
@set tengo_pala
Cojo la pala y, tras cerrar el cobertizo, la muevo un par de veces y golpeo el suelo del sendero con el canto y la punta; saltan un par de chispas pero no se astilla y el mango se mantiene recto.
Me gusta, la pala: no tiene la masa del chuzo o la picota, pero se maniobra mucho mejor; vaya a saber de qué estará hecha, pero es liviana y extremadamente dura. Si se tercia, sirve contra la mayoría de los bichos.
Con la [pala al hombro], me dirijo tranquilo [[hacia el barbecho]](sendero).
[pala al hombro]:
Cuando llegué a la estación, apenas notaba el peso de la pala. Ahora, tengo que acordarme que la llevo.
[[chuzo]]:
@clear
@set tengo_chuzo
Cojo el chuzo y, tras cerrar el cobertizo, lo muevo un par de veces y golpeo el suelo del sendero con la punta; saltan un par de chispas y astillas del suelo, pero el chuzo apenas vibra y se mantiene recto.
Me gusta, el chuzo, aunque menos que la pala: pesa lo suyo, y se maniobra con dificultad, pero no hay herramienta en la estación que me dé una sensación tan... atávica de seguridad. Es una pieza pesada, durísima... y eficaz contra cualquier bicho.
Y me consta.
Con el [chuzo al hombro], me dirijo tranquilo [[hacia el barbecho]](sendero).
[chuzo al hombro]:
Cuando llegué a la estación, podía sostener el chuzo a dos manos, pero era torpe; no lograba balancearlo bien. Ahora, puedo hacer guaripolas con este hierro...
[[sendero]]:
@clear
Llevo medio camino andado hacia el barbecho, hecho unas pascuas, cuando noto que los helechos se mueven a mi derecha... y se escucha un ruido como el que haría un cerdo hozando entre las matas.
Bichos.
¡Mierda!
Ya sabía yo que el día empezaba demasiado bien.
Por el volumen del ruido y el movimiento de las plantas no parece que sea algo demasiado peligroso; podría atenderlo más tarde y [[seguir mi camino]](rastros)...
...o [[echar una mirada]] y ver si es algo que puedo despachar rápido.
[[echar una mirada]]:
@clear
Con cuidado, aparto las plantas con {if seen pala:la pala}{else:el chuzo} y miro entre la espesura.
Es una oruga, comiendo helechos como si no hubiera mañana.
¡Joder, qué susto que he pasado!
Es sólo una oruga; que sí, que mide un metro de largo y pesará sus 100 kilos, pero es una puta oruga: no me va a perseguir, no va sacar crías ya mismo y sólo está comiendo helechos, que aquí crecen como maleza y me importa un bledo si se los come hasta hacerse pupa (je).
Bueno, [[nada me cuesta despacharla]](oruga) y luego sigo con lo mío... aunque igual [[la dejo para más tarde]](rastros) que tampoco pasa nada.
[[oruga]]:
@inc puntaje
La verdad, esto es cosa de momentos y es mejor no acumular trabajo para la tarde.
Tomando impulso, doy un salto y le caigo encima con la punta de{if seen pala: la pala}{else:l chuzo}.
{if seen pala:Le corto la cabeza antes de que se dé cuenta de qué está pasando y con rapidez corto el resto del cuerpo en unos 15 pedazos.}
{else:Hago palanca con violencia, separando la cabeza del cuerpo y perforo el resto unas 20 veces, desinflándola de sus fluidos corporales.}
Los helechos quedan hechos un asco y la oruga está [bien muerta].
Bueno, limpiaré esto más tarde... si es que la vuelta los [otros bichos](bichitos) no han dado cuenta de los restos, claro.
Con una preocupación menos, [[sigo mi camino]](rastros).
[bichitos]:
La verdad, los bichos chicos no son mejores ni más fáciles de aniquilar que los grandes: se mueven más rápido y si me descuido con la fumigación pueden venir en números de verdad importantes; ahí no me queda otra que encerrarme en el refugio y activar los drones... que matan a todos los bichos, sí, pero me dejan las plantas hechas un asco y a veces tengo que empezar de cero con los brotes tiernos. Una lata.
[bien muerta]:
La pobre oruga quedó {if seen pala:servida para sushi}{else:lista para carne mechada}...
[[rastros]]:
@clear
Con {if seen echar una mirada:algo de alivio}{else:pies de plomo} voy avanzando al barbecho.
Putos bichos... le quitan a uno el gusto por el trabajo agrario, joder.
Voy tan concentrado pensando en {if seen pala:qué hoyos voy a cavar y dónde}{else:qué terreno voy a picar y cuánto} que no atino con el rastro que cruza el sendero hasta que lo tengo encima.
Es una huella de [babas](baba caracol) densa, brillante, como de un metro de ancho, que cruza el sendero de lado a lado... y se ve que es fresca, por suerte: todavía despide ese vaho [irritante].
Me cago en la jardinería: hay un caracol grande aquí cerca... y como no me cargue al bicho pronto, empezará a poner huevos vaya usted a saber [dónde] y tendré una infestación en menos de lo que dices "plaga".
Por lo visto, mi día comienza con un poco de entomología agresiva. Y con lo bien que había empezado el día, joder...
El [manual de operaciones] indica que, en estos casos, primero hay que [[evaluar la amenaza]]. En mi barrio, en cambio, dicen que [[primero protegido]](equipamiento) que luego arrepentido.
Decisiones, decisiones...
[baba caracol]:
Parece como si un dinosaurio hubiera estornudado en medio del sendero.
[irritante]:
La baba está empezando a evaporarse, pero tocarla sin guantes te deja una quemada fea. Me consta.
[dónde]:
Lo habitual con los caracoles (da igual el tamaño) es que desoven entre los helechos y las matas, pero los he visto subirse a árboles y dejar sus nidos a varios metros de altura, no te jode.
[manual de operaciones]:
El manual de operaciones, diseñado y mantenido por los chicos de la [Estación Central], es más bien breve y al grano, lo que a veces es bueno y otras veces te deja a merced de tu propio criterio. Se supone que debo llevarlo en el sobre transparente de la manga del mono de trabajo, pero es una lata y ya me lo sé casi de memoria.
[Estación Central]:
La Estación Central está más o menos al centro de las demás estaciones y desde ahí nos despachan los trabajos a cada estación. Con la carga de trabajo que tienen, cuesta creer que tengan tiempo para manuales, pero de algún modo se las arreglan.
[[equipamiento]]:
@clear
@inc puntaje
@set traje_puesto
La verdad, y visto lo peligrosa que llega a ser la [baba](irritante) de estos bichos, no quiero ni acercarme a mirarlo si no estoy con algo de protección "extra".
A la carrera, que con los caracoles el tiempo apremia (je), me vuelvo al cobertizo y me pongo el [traje] para control de plagas. Es como ponerse un traje espacial, pero sin ayuda, vaya.
Más tranquilo, me devuelvo a paso vivo
{if seen evaluar la amenaza: para [[acabar con esta alimaña]](atacar) de una puñetera vez.}
{else: y comienzo a [[seguirle el rastro a esta bestia asquerosa]](evaluar la amenaza)...}
[irritante]:
Tocar la baba de los caracoles gigantes sin guantes te deja una quemada fea. No gracias.
[traje]:
Los trajes de control de plagas son como mi mono de trabajo, pero mucho más gruesos e incómodos: están presurizados, con escafandra y sistema de aire autónomo. No es que me guste ponérmelos, pero ni mamado me voy a cazar bichos como un caracol gigante así sin más. El mono de trabajo no es una armadura estanca; el traje sí.
[[evaluar la amenaza]]:
@clear
Apartando las plantas, y cuidando de no pisar ramitas u hojas que me delaten, comienzo a seguir el rastro de babas... tarea sencilla; el suelo está como si alguien hubiera pasado con una podadora industrial por la espesura.
Aparte de la mugre que deja el bicho, nada queda tras su paso.
A los pocos metros ya puedo oírlo
{if seen equipamiento: aunque, gracias al traje, no tengo que olerlo; haber estado cerca de sus babas ya fue suficiente.}
{else:y por desgracia puedo olerlo; sus babas eran apenas un pálido heraldo de la [peste] de la criatura.}
Avanzo y por fin lo diviso 10 metros adelante, al pie de un árbol, masticándole sus raíces como si fueran hierbas.
Joder.
Debe medir de hocico a cola unos 3 metros... y la concha, que parece hecha de piedra, ha de ser de 2 metros de alto o así.
No me atrevo ni a {if seen protegido: [respirar fuerte], traje con estanco o no}{else:[suspirar](respirar fuerte)}.
{if seen pala:Con la pala, liviana como es, corro menos riesgos de movilidad, pero no creo que sirva contra el caparazón.. y por el frente tengo dudas de tener más de una oportunidad.}
{else:Con el chuzo, que pesa lo suyo, me oirá en cuanto me le acerque, pero creo puedo reventarle el caparazón a golpes antes de que pueda reaccionar.}
Y luego, están las [babas].
Mierda y más mierda.
{if traje_puesto:
A menos que el animal se me eche encima, el traje debiera protegerme de sus "salpicaduras" o la eventual mordida.
{if seen pala: La pala tendrá que bastarme}
{else: El chuzo me bastará}
para acabar con el caracol.
Bueno, basta ya de pendejadas. ¡Voy a acabar con este cabrón [[ahora]](atacar)!
}
{else:
Dudo que el mono de trabajo me proteja si el animal se me eche encima, o en caso de que me "salpique", para no hablar de que me llegue a morder.
Así las cosas, no sería mala idea volver al cobertizo a [[buscar una mejor protección]](equipamiento)... o dejarme de pendejadas y arriesgarme a [[acabar ya mismo con este cabrón]](atacar).}
[peste]:
Antes de venir a la estación botánica trabajé en una fundición de metales pesados... y los crisoles olían mejor que este caracol.
[respirar fuerte]:
Aunque no les vea las orejas, tienen buen oído... y sienten cualquier movimiento en el suelo a 5 pasos o así.
[babas]:
Nunca he peleado un "mano a mano" con estos bichos... pero si la "conchita" es alguna indicación de lo "avanzado" del animal, puede que no se limite a dejar babas mientras avanza.
[[atacar]]:
@clear
Irrumpo sigiloso en el erial formado por las babas del caracol, que
{if traje_puesto:
{if seen pala: sigue comiendo como si nada, ignorándome por completo.}
{else: deja de masticar por un instante.}
}
{else: en ese momento deja de masticar
{if seen pala: y se queda inmóvil.}
{else: y casi instantáneamente gira sus ojos hacia mí.}
}
No le doy tiempo a reaccionar y le ataco de inmediato
{if seen pala: golpeándole el caparazón con el filo de la pala...
que rebota sin causarle el más mínimo daño.
De la cabeza del caracol sale un siseo...}
{else: embistiendo el caparazón con la punta del chuzo, penetrando con un crujido horrible.
De la cabeza del caracol sale un chillido agudo...}
y el animal levanta la cola, despegándola del suelo con un ruido líquido.
Durante un brevísimo instante creo recordar algo parecido...
...de otro animal...
...en otro tiempo y lugar...
...y entonces la cola del caracol [[escupe una lluvia de babas]](lluvia de babas).
[[lluvia de babas]]:
Atino a cubrir mi cara con la manga del
{if traje_puesto: traje, que recibe las gotas de lleno... sin que parezcan afectarlo; escurren al suelo, que comienza a humear de inmediato.}
{else: mono, que empieza a consumirse ahí donde caen las gotas.
Aunque sé que ya es tarde, intento retroceder, pero en mi apuro me enredo con {if seen pala: la pala}{else:el chuzo}... y [[caigo de espalda sobre el rastro de babas]](muerte).}
{if traje_puesto:
{if seen pala: La pala no vale nada con la concha, así que iré a por las partes blandas.
Puedo intentar [[atacarlo por la cola]](mátalo sucio) y cortar con las babas... o arriesgarme e [[ir a por la cabeza]](mátalo limpio)}
{else: Bueno, basta de tonterías: es hora de [[rematar a este cabrón]](mátalo limpio)}.}
[[mátalo sucio]]:
@inc puntaje
Para evitar más duchas viscosas, cojo la pala a dos manos, salto y le caigo encima de la cola con la punta de la pala; con un satisfactorio crujido y un ruido líquido le cerceno la cola...
... y una explosión de babas cubre todo alrededor mío, mientras el caracol da un verdadero rugido.
Asqueado, lo rodeo en un par de pasos y lo corto la cabeza de un solo golpe.
El animal [yace inerte].
Las babas del bicho gotean por mi traje y contemplo las plantas a mi alrededor: todo humea y se consumen ante mis ojos, como si alguien hubiera usado una manguera de incendios con ácido en el lugar.
El árbol, con la base consumida por la corrosión y sus raíces socavadas y deshechas, cae derribado.
De la pala, sólo me ha quedado el mango.
[[Joder, qué desastre]](final)...
[yace inerte]:
El pobre animal parece un amouse bouche escargot...
[[mátalo limpio]]:
@inc puntaje
@inc puntaje
{if seen pala:Quiero terminar con esto rápido, así que cojo la pala a dos manos, rodeo al caracol en un par de pasos y lo corto la cabeza de un solo golpe.
El animal [yace inerte].}
{else:Con más furia que antes, embisto al caracol con todo mi peso apoyado en el chuzo.
Joder: lo arponeo, atravesando la concha y luego la cabeza del bicho, dejando la punta del chuzo clavada al tronco del árbol.
El animal no alcanzó ni a suspirar y ha quedado [completamente inerte].}
Las babas del bicho gotean por mi traje y contemplo las plantas a mi alrededor: algunas hojas humean y se consumen ante mis ojos, pero no hay mayores daños.
El árbol tiene algunas raíces mordidas y alguna escoriación menor en el tronco, pero nada que un emplasto de tierra y abono no pueda curar.
Nada mal para una exterminación: limpia y sin daños colaterales.
Qué digo... ¡[[si soy el puto amo de esta estación]](final)!
[yace inerte]:
El pobre animal parece un amouse bouche escargot...
[completamente inerte]:
El pobre caracol quedó como una gigantesca y grotesca brocheta...
[[final]]:
@clear
{if seen mátalo sucio:Bueno, tengo que despejar este terreno... y mandar una orden de adquisición para otra pala.
Menuda faena me espera: y eso, si no deciden "prescindir" de mí y traer un reemplazo.
En fin, que fue una buena semana... hasta hoy.}
{else: Bueno, tengo que volver al laboratorio y traer un frasco: seguro que querrán muestras del bicho...
...y quién sabe: a lo mejor me cae una "visita amistosa" cuando termine mi turno: hay que hacer crecer la población sólo con "buena cepa", je.}
Tengo un [reporte] que hacer, así que camino de vuelta al laboratorio a paso {if seen mátalo sucio:lento y cansino: ha sido una victoria a lo Pirro, joder}{else:vivo y ganoso: esto lo anima a uno a seguir luchando todos los días}.
Contemplo una vez más la estación con una mirada {if seen mátalo sucio:algo abatida}{else:nueva e inquieta}; cuesta creer que más allá del perímetro de seguridad no hay más que arena y asfixia. No estamos demasiado mejor que los pobres [Espaciales]... pero tenemos suelo y gravedad naturales bajo los pies, al menos.
Exceptuando aquí y allá los domos de nuestras estaciones en funciones y los cráteres de [algunas estaciones fallidas](estaciones fallidas), estamos en medio de un desierto árido, completamente yermo, helado... y rojo.
Así, precaria, avanza la [[colonización de Marte]](Marte)...
[reporte]:
En la Estación Central estiman que se aprende mucho de los éxitos, pero aún más de los tropiezos. Vaya si seremos todos optimistas, pero los de la Estación Central son el no va más...
[Espaciales]:
Unos tipos duros, los Espaciales. Hemos tratado de reclutar entre ellos, pero no les convence nuestro "estilo rural". Teníamos a uno medio convencido, pero tomó un OTV y se fué a los asteroides camino de Júpiter, creo.
[estaciones fallidas]:
Una se ha perdido en un azote descontrolado de plagas, otra en un "accidente" al mezclar químicos (el operador era imbécil, vaya) y otra más por una descompresión explosiva. Considerando todas las otras cosas que pueden irse al diablo en una estación, es sorprendente que sean tan pocas las instalaciones que han fallado... hasta ahora.
[[Marte]]:
@clear
Una colonización más bien lenta, sobre todo porque, como estas estaciones demuestran, aún no terminamos de entender qué diablos pasó en este planeta para que quedara así ni por qué su suelo reacciona como lo hace con nuestras plantas.
Para no hablar de los animales, por cierto: todo lo que nace y crece en contacto con el suelo marciano muta rápidamente a un estado casi prehistórico, lo que nos tiene a todos completamente apabullados... y a los encargados de demografía y crecimiento poblacional algo preocupados, la verdad.
A lo mejor ya ha pasado en otra parte, [vaya uno a saber], pero si en la [Estación Central] lo saben, no nos lo han dicho; la información innnecesaria es casi tan peligrosa como la información falsa, ya se sabe.
Porque así están las cosas: no hay regreso posible a la Tierra, menos de la manera apresurada y precipitada que se hizo nuestra "migración", a espalda de cualquier gobierno, "compañía" o ricachones de turno que quisieran cosechar nuestros logros.
Sin ataduras... y sin apoyos: baja tasa de retorno de [inversión] ¿saben?
Así que tenemos que salir adelante con lo que hay y lo que somos o seremos; ésa es la primera regla de la colonización de Marte.
Afíncate o muérete.
De momento, tengo un reporte que llenar... y luego {if seen mátalo sucio:puede que tenga que buscarme la vida}{else: un terreno en barbecho que cuidar}.
Qué día...
{if seen mátalo sucio:
Has terminado por hoy}
{else:
Has vencido... por hoy}
Puedes revisar tu [puntuación](Puntuación), leer los [agradecimientos](Agradecimientos), mirar las [curiosidades](Curiosidades), saber algo más [acerca de "Rastros"](Acerca de) o [[reiniciar]](Reiniciar) el relato.
[vaya uno a saber]:
Hay rumores de que una de las compañías mineras tuvo un lío de macetas en el cinturón de asteroides camino a Júpiter, pero no hay nada claro.
[Estación Central]:
La Estación Central está más o menos al centro de las demás estaciones y desde ahí se coordinan los trabajos de nuestra pequeña colonia. Se puede postular a trabajar ahí, pero el proceso de selección es muy riguroso y la carga de trabajo no es mejor que en las estaciones botánicas.
[inversión]:
El dinero, en Marte, está en las plataformas orbitales de las compañías a cargo de explotación minera. Será que es menos riesgoso el espacio que colonizar Marte, no te jode...
[Puntuación]:
Has conseguido {puntaje} punto{if puntaje=1: }{else:s }de 5 así que calificas como
{if puntaje=0: pisaverde
Te limitaste a pasear por el lugar...}
{if puntaje=1: desmalezador}
{if puntaje=2: podador de césped}
{if puntaje=3: paisajista al uso}
{if puntaje=4: jardinero}
{if puntaje=5: exterminador de plagas}
{if seen laboratorio:+1 Llevaste muestras al laboratorio
}
{if seen oruga:+1 Mataste una oruga
}
{if seen equipamiento:+1 Te pusiste el traje para control de plagas
}
{if seen final:
{if seen mátalo sucio:+1 Exterminaste al caracol con la pala y comenzando por la cola: qué desastre...
}
{else:+2
{if seen pala: Exterminaste al caracol con la pala y decapitándolo}{else: Exterminaste al caracol con el chuzo}: un trabajo limpio...
}
}
[Agradecimientos]:
El autor quiere agradecer a:
* Comely, por su testing alfa
* Fernando Gregoire, por su testing beta
* Alex Warren, por crear Squiffy, con el que pude construir este hiperrelato
[Curiosidades]:
Algunas curiosidades para encontrar en una nueva lectura de "Rastros":
* Algunos bichos quedan "servidos" según cómo se les extermina; fíjate en los detalles una vez que los has matado.
* El espacio es la frontera final, pero la colonización planetaria tiene sus riesgos. Lee entre líneas y verás por qué.
* Los chicos de la Estación Central están en todo. A veces, en detalles insospechados.
[Acerca de]:
Sobre la Creación de la Obra
Estaba revisando la publicación de mis anteriores trabajos en textadventures.co.uk cuando ví un enlace a un sistema de creación de hiperrelatos llamado Squiffy.
Su sencillez, potencial y sobre todo la rapidez con que permite crear este tipo de ficciones interactivas me sedujo y me animó a escribir nuevamente un relato interactivo, después de casi 5 años de "silencio".
El resultado está ante ustedes.
Sobre el Tema de la Obra
Siempre que se habla de la colonización del espacio, la gente imagina emocionantes epopeyas de aventura y riesgo en el espacio, la frontera final...
...pero la verdad es que, cuando se haga, la colonización del espacio y de otros mundos tendrá todas las pequeñas alegrías, dificultades y miserias del día a día de los seres humanos de estos tiempos y de todos los tiempos, porque tanto no ha de haber cambiado el ser humano cuando definitivamente se lance a las estrellas.
Algo de eso he querido reflejar en "Goteras" y "Macetas", los 2 trabajos anteriores de esta saga de Espaciales.
Si este tercer relato lo consigue o no, queda a juicio del lector.
Santiago de Chile, 4 de Julio, 2016
[[muerte]]:
Escucho el siseo de mi mono e intento rodar antes de que se consuma por completo, así que no puedo esquivar un segundo escupitajo del caracol, más abundante que el anterior.
Las babas me golpean en todas partes, incluyendo la cara; siento quemaduras como si me estuvieran asando y mi visión se nubla por completo.
Manoteando inútilmente, no logro salir del paso del caracol, que me cae encima con todo su peso...
...soy su jodido postre...
Has muerto
Puedes revisar tu [puntuación](Puntuación), leer los [agradecimientos](Agradecimientos), mirar las [curiosidades](Curiosidades) o [[reiniciar]](Reiniciar) el relato.
[Puntuación]:
Has conseguido {puntaje} punto{if puntaje=1: }{else:s }de 5 así que calificas como
{if puntaje=0: pisaverde
Te limitaste a pasear por el lugar...}
{if puntaje=1: desmalezador}
{if puntaje=2: podador de césped}
{if puntaje=3: paisajista al uso}
{if puntaje=4: jardinero}
{if puntaje=5: exterminador de plagas}
{if seen laboratorio:+1 Llevaste muestras al laboratorio
}
{if seen oruga:+1 Mataste una oruga
}
{if seen equipamiento:+1 Te pusiste el traje para control de plagas
}
{if seen final:
{if seen mátalo sucio:+1 Exterminaste al caracol con la pala y comenzando por la cola: qué desastre...
}
{else:+2
{if seen pala: Exterminaste al caracol con la pala y decapitándolo}{else: Exterminaste al caracol con el chuzo}: un trabajo limpio...
}
}
[Agradecimientos]:
El autor quiere agradecer a:
* Comely, por su testing alfa
* Fernando Gregoire, por su testing beta
* Alex Warren, por crear Squiffy, con el que pude construir este hiperrelato
[Curiosidades]:
Algunas curiosidades para encontrar en una nueva lectura de "Rastros":
* Algunos bichos quedan "servidos" según cómo se les extermina; fíjate en los detalles una vez que los has matado.
* Si quieres saber dónde está este "jardín de las delicias", intenta completar este relato sin que te maten...
[[Reiniciar]]:
squiffy.story.restart();